Tính độ co dãn của hàm cầu – Stata

II. Mô hình độ co dãn không đổi và độ co dãn thay đổi.

Thuật ngữ độ co dãn (elasticity) được sử dụng để mô tả hệ số của mô hình: ln(y) = a4 + b4*ln(x). Đây được gọi là mô hình có độ co dãn không đổi (constant elasticity model). Khi đó b1 chính là độ co dãn của y theo x. Hay nói cách khác, độ co dãn của mô hình log-log đơn giản nhất chính là hệ số cắt được ước lượng của mô hình.

Tuy nhiên, khi chúng ta ước lượng mô hình: y = a1 + b1*x. Với mô hình này, chúng ta có thể tính độ co dãn tại bất kì giá trị x nào chúng ta muốn. Vì vậy, mô hình này còn được gọi là mô hình độ co dãn thay đổi (varying elasticity model).

Trong ví dụ sau, chúng ta sẽ tính vẽ độ co dãn của biến bằng lệnh margins theo giá trị của biến độc lập ở cả mô hình có độ co dãn không đổi và thay đổi.

sysuse auto, clear
keep mpg weight
sum weight
local mean=r(mean)
*——constant elasticity model——
gen lnmpg=ln(mpg)
gen lnwei=ln(weight)
regress lnmpg lnwei
gen marg_cons=_b[lnwei]
*——varying elasticity model——
regress mpg weight
*——elasticity at the mean——
margins, eyex(weight) atmeans
matrix A=r(b)
gen marg_mean = A[1,1]
*——elasticity at different values of weight——
margins, eyex(weight) at(weight = (1750(250)5000)) noatlegend
marginsplot, noci xlabel(2000(1000)5000) addplot(line marg_cons wei || line marg_mean wei, xline(`mean’) legend(order(1 “varying” 2 “constant” 3 “mean”) rows(1)))

Nhận xét: các điểm trên trên đồ thị chính là các độ co dãn tại các giá trị trung bình của biến độc lập. Đường nằm ngang trên đồ thị ứng với giá trị của độ co dãn không đổi của mô hình log-log.